Taskbar static pupup

[c-tec]

Hello,
I am using the Taskbar sample to control a application. Works so far, but I would like to popup a little static in the lower left corner with some infos (icons and buttons) instead of the menu. Is this possible ?
regards
Rudolf

[c-tec]

Hello
additionally I would like to zoom in (with transparency or so) a little static in my programs when the user goes over a specified region in the application screen and the static gets hidden again when the user leave the region of the static. I am shure this is possible with eXpress and a event handler.
regards
Rudolf

[rdonnay]

The below code shows how to do the zoom and transparency.

Code: Select all

#INCLUDE "dcdialog.CH"

FUNCTION Main( cUser )

LOCAL GetList[0], GetOptions

DEFAULT cUser := 'Roger Donnay'

@ 2,0 DCSAY cUser FONT '10.Arial Bold' COLOR GRA_CLR_YELLOW
@ 3,0 DCSAY 'has come on line' COLOR GRA_CLR_YELLOW

DCGETOPTIONS COLOR GRA_CLR_DARKCYAN SAYWIDTH 0 ;
   WINDOWROW -300 WINDOWCOL -300 HIDE

DCREAD GUI FIT TIMEOUT 5 ;
   TITLE 'IM Alert' ;
   BUTTONS DCGUI_BUTTON_OK ;
   OPTIONS GetOptions ;
   EVAL {|o|DC_SetWindowTransparency(o:getHwnd(),100), ;
            Sleep(1), ;
            o:show(), ;
            o:setPos({0,-1*o:currentSize()[2]}), ;
            ShowNewUserWindow(o)}

RETURN nil

* -------------

STATIC FUNCTION ShowNewUserWindow( oDlg )

LOCAL i, nHeight := oDlg:currentSize()[2], nHandle, nTransparency

nHandle := oDlg:getHwnd()

FOR i := 1 TO nHeight STEP 5
  Sleep(5)
  oDlg:setPos({oDlg:currentPos()[1],oDlg:currentPos()[2]+5})
  nTransparency := Int(100-i)
  IF nTransparency > 0
    DC_SetWindowTransparency(nHandle,nTransparency)
  ENDIF
  oDlg:setSize({oDlg:currentSize()[1]+2,oDlg:currentSize()[2]})
NEXT
DC_SetWindowTransparency(nHandle,0)
RETURN nil

* ----------

PROC appsys ; RETURN

[c-tec]

Hello Roger,
thank you, works perfect for me
regards
Rudolf