bb.donnay-software.com

Code: Select all

METHOD DC_XbpTabPage:WhenHideEval( lEnable, lShow, lProtect )

LOCAL lMinimized := ::minimized, aColors, lEnabled

IF Valtype(::whenBlock) == 'B'
  lEnabled := Eval(::whenBlock,self)
  IF lEnabled .AND. !::isEnabled()
    lEnable := .t.
    ::Enable()
  ELSEIF !lEnabled .AND. ::isEnabled()
    ::Disable()
  ENDIF
  IF Valtype(::saveColor)='N' .AND. ::saveColor # ::colorBG
    ::Maximize()
    IF lMinimized
      ::Minimize()
    ENDIF
  ENDIF
  ::saveColor := ::colorBG
ENDIF

IF Valtype(::hideBlock) = 'B'
  lShow := !Eval(::hideBlock,self)
  IF lShow
    IF !Empty(::initPos)
      ::setPos(::initPos)
      ::initPos := nil
    ENDIF
  ELSE
    IF Empty(::initPos)
      ::initPos := ::currentPos()
      ::setPos( {-2000,-2000})
    ENDIF
  ENDIF
ENDIF

IF ::isEnabled()
  IF Valtype(::enabledColorBlock) = 'B'
     aColors := Eval(::enabledColorBlock,self)
     DEFAULT aColors := {}
     ASize(aColors,2)
     ::enabledColorFG := ConvertColor(aColors[1])
     ::enabledColorBG := ConvertColor(aColors[2])
  ENDIF
  IF Valtype(::enabledColorBG)='N' .AND. !(::setColorBG() == ::enabledColorBG)
    ::setColorBG(::enabledColorBG)  // enabled BG color
  ENDIF
  IF Valtype(::enabledColorFG)='N' .AND. !(::setColorFG() == ::enabledColorFG)
    ::setColorFG(::enabledColorFG)  // enabled FG color
  ENDIF
ELSE
  IF Valtype(::disabledColorBlock) = 'B'
    aColors := Eval(::disabledColorBlock,self)
    DEFAULT aColors := {}
    ASize(aColors,2)
    ::disabledColorFG := ConvertColor(aColors[1])
    ::disabledColorBG := ConvertColor(aColors[2])
  ENDIF
  IF Valtype(::disabledColorBG)='N' .AND. !(::setColorBG() == ::disabledColorBG)
    ::setColorBG(::disabledColorBG)  // disabled BG color
  ENDIF
  IF Valtype(::disabledColorFG)='N' .AND. !(::setColorFG() == ::disabledColorFG)
    ::setColorFG(::disabledColorFG)  // disabled FG color
  ENDIF
ENDIF

IF Valtype(::protectBlock) = 'B'
  lProtect := Eval(::protectBlock,self)
ENDIF

RETURN self